* Join Date: Sep 2003
* Location: Texas
* 	
* This is a PSpice model. If you need a Berkeley model, let me know.
* 
* Be careful with the LOG function. In this model it means natural log, which is sometimes written as LN. If your simulator uses LN for natrual log, then replace LOG with LN. If not, you're ok.
* 
* If you don't know, plot the curves. If they look right then you're good. If not, change it to LN and it should look right.
* 
*
* Triode Model for ECC99
*
* Alex Cavalli
* 2003
*
* Based on models from Norman Koren
*
* Grid current is modeled with a diode.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
.SUBCKT ECC99 1 2 3 ; P G C; NEW MODEL
E1 7 0 VALUE=
+{V(1,3)/500*LOG(1+EXP(500*(1/22+V(2,3)/SQRT(300+V(1,3)*V(1,3)))))}
G1 1 3 VALUE={(PWR(V(7),1.3)+PWRS(V(7),1.3))/362}
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 5.8p
C2 2 1 5.1p
C3 1 3 0.91p
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 2000 ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=0 TT=1N)
.ENDS